$Title Dienstplanung
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 3.3 Personaleinsatzplanung
Problemstellung: Bildung zulaessiger Schichtmusterfolgen fuer Mitarbeiter

 - Model -

Author: Rui Guo
Date: 18/12/2019

$Offtext

$eolcom//

$include days-off-scheduling_data.gms

variables
   nutzen    Summe der Nutzenwerte (Zielfunktion)
   x(k,t,s)  gleich 1 falls Mitarbeiter k an Tag t dem Schichtmuster s zugewiesen wird ;

binary variable x ;

equations
   def_nutzen                  Definition des Gesamtnutzens
   muster_mitarbeiter(k,t)     Zuweisung eines Musters an Mitarbeiter k fuer Tag t
   inkompatibel(k,t,s,sPrime)  Vermeidung verbotener Musterpaare
   bedarf(t,s,q)               Bereitstellung der benoetigten Anzahl an Mitarbeitern mit Qualifikation q in Muster s fuer Tag t
   muster_min(k,s)             Einhaltung der minimalen Anzahl an Tagen an denen Mitarbeiter k Muster s zugewiesen wird
   muster_max(k,s)             Einhaltung der maximalen Anzahl an Tagen an denen Mitarbeiter k Muster s zugewiesen wird ;

   def_nutzen..                                            nutzen =e= sum((k,t,s)$s_of_t(s,t), u(k,s)*x(k,t,s)) ;
   muster_mitarbeiter(k,t)..                               sum(s$s_of_t(s,t), x(k,t,s)) =e= 1 ;
   inkompatibel(k,t,s,sPrime)$((ord(t)<card(t)) and verboten(s,sPrime))..
                                                           x(k,t,s)+x(k,t+1,sPrime) =l= 1 ;
   bedarf(t,s,q)$(s_of_t(s,t) and (not sameas(s,'s0')))..  sum(k$skilled(k,q), x(k,t,s)) =g= r(t,s,q) ;
   muster_min(k,s)$(not sameas(s,'s0'))..                  n_min(k,s) =l= sum(t$s_of_t(s,t), x(k,t,s)) ;
   muster_max(k,s)$(not sameas(s,'s0'))..                  sum(t$s_of_t(s,t), x(k,t,s)) =l= n_max(k,s) ;

model days_off_scheduling / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve days_off_scheduling maxmizing nutzen using mip ;

display nutzen.l, x.l ;