$Title Standortplanung regenerativer Kraftwerke
$Ontext

Vorlesung: Betriebliche Planung von Energiesystemen
Abschnitt: 2.3 Standortplanung fuer regenerative Kraftwerke
Problemstellung: Markowitz-Modell fuer das bikriterielle Standortplanungsproblem zur Maximierung des Ertrags und der Verlaesslichkeit

 - Model -

Author: Christoph Schwindt
Date: 20/12/2019

$Offtext

$eolcom//

$include location-renewable_data.gms

***** Maximum-Value-Modell *****

variables
   arbeit  Erwartungswert der gesamten erzeugten elektrischen Arbeit
   z(i)    Nennleistung am Standort i
   y(i)    gleich 1 falls am Standort i Anlage errichtet ist oder wird ;

binary variables y ;
positive variables z ;

equations
   def_arbeit       Definiere gesamte elektrische Arbeit
   budget           Einhaltung des Budgets
   min_leistung(i)  Einhaltung der unteren Grenze fuer die Nennleistung am Standort i
   max_leistung(i)  Einhaltung der unteren Grenze fuer die Nennleistung am Standort i ;

   def_arbeit..       arbeit =e= sum(i, sum(t, p(i,t))*z(i)) ;
   budget..           sum(i$(not ex(i)), a(i)*y(i)) + sum(i, b(i)*(z(i)-z0(i))) =l= capital_B ;
   min_leistung(i)..  z(i) =g= zUnder(i)*y(i) ;
   max_leistung(i)..  z(i) =l= zBar(i)*y(i) ;

   y.fx(i)$ex(i) = 1 // y-Variable fuer existierende Anlagen i gleich 1

model max_value / def_arbeit, budget, min_leistung, max_leistung / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve max_value maximzing arbeit using mip ;

scalar max_arbeit  Optimaler Zielfunktionswert Max-Value-Modell ;
   max_arbeit = arbeit.l ;

display 'Loesung Maximum-Value-Modell', arbeit.l, y.l, z.l ;

***********************************
***** Minimum-Variance-Modell *****

variable
   stabw  Summe der Periodenstandardabweichungen elektrischer Leistung ;

equation
   def_stabw  Definition der Summe der Periodenstandardabweichungen ;

   def_stabw..  stabw =g= sum(t, sqrt(sum((i,j), c(i,j,t)*z(i)*z(j)))) ; // =g= damit Goal-Programming-Modell konvex

model min_variance / def_stabw, budget, min_leistung, max_leistung / ;

options minlp = dicopt // Relaxation des Min-Variance-Modells ist konvexes Programm
        optcr = 0
        reslim = 60 ;

solve min_variance minimizing stabw using minlp ;

scalar min_stabw  Optimaler Zielfunktionswert Min-Variance-Modell ;
   min_stabw = stabw.l ;

display 'Loesung Minimum-Variance-Modell', stabw.l, y.l, z.l ;

***********************************
***** Goal-Programming-Modell *****

variable
   distanz  Distanz im Zielraum zu Kombination monokriterieller Optima ;

equation
   def_distanz  Definition der Distanz ;

   def_distanz..  distanz =e= sqrt(sqr(arbeit-max_arbeit)+sqr(stabw-min_stabw)) ;

model goal_programming / def_distanz, def_arbeit, def_stabw, budget, min_leistung, max_leistung / ;

options minlp = dicopt // Relaxation des Gola-Programming-Modells ist konvexes Programm
        optcr = 0
        reslim = 60 ;

solve goal_programming minimizing distanz using minlp ;

display 'Loesung Goal-Programming-Modell', distanz.l, arbeit.l, stabw.l, y.l, z.l ;

***********************************